Dùng Macro 4 để lấy dữ liệu từ 1 file đang đóng
Loại bài toán này đã từng được nói rất nhiều lần trên diễn đàn rồi. Hầu hết người ta dùng 2 cách:
Cách 1: Mở file để lấy dữ liệu rồi đóng file lại
Cách 2: Dùng ADO (không thấy mở file nhưng vẫn có mở ngầm)
Hôm nay xin giới thiệu với bạn 1 cách cực kỳ đơn giản (tự các bạn xây dựng). Bẳng cách dùng Macro 4, các bạn sẽ thấy giải thuật đơn giản đến không ngờ
Tất cả bắt đầu bằng những thí nghiệm sau đây:
– Giả sử ta có file Source.xls và file Main.xls nằm cùng 1 thư mục
– File Source.xls là file chứa nguồn dữ liệu
– Ta mở 2 file cùng lúc. Tại file Main, sheet1, cell A1, tôi gõ dấu = , xong tôi dời con trỏ sang file Source.xls rồi nhấp chọn cell A1
– Sau khi thực hiện xong ta được công thức =Sheet1!$A$1
– Đóng file Source.xls, ta thấy công thức tại cell A1 của file Main.xls đã biến đổi, có thêm đường dẩn tuyệt đối… đại khái thế này
='C:Documents and SettingsNHAVDesktopGetData_TestSheet1'!$A$1
– Giở ta bật chức năng record macro lên, chọn cell A1, bấm F2 và Enter… xong, tắt record macro và Alt + F11 để xem code, ta sẽ thấy code có dạng thế này:
Sub Macro1()
'
' Macro recorded 17/8/2010 by Anh Tu?n
'
'
Range("A1").Select
ActiveCell.FormulaR1C1 = _
"='C:Documents and SettingsNHAVDesktopGetData_TestSheet1'!R1C1"
Range("A2").Select
End Sub
– Chỉnh sửa code lại 1 tí:
Sub Macro1()
Range("A1") = "='C:Documents and SettingsNHAVDesktopGetData_TestSheet1'!R1C1"
End Sub
– Code này làm công việc gán công thức liên kết đến file Source.xls vào cell A1 của file Main.xls
– Để chuyển công thức thành giá trị, ta có 2 cách
Cách 1:
Sub Macro1()
With Range("A1")
.Value = "='C:Documents and SettingsNHAVDesktopGetData_TestSheet1'!R1C1"
.Value = .Value
End With
End Sub
Cách 2:
Sub Macro1()
Range("A1") = ExecuteExcel4Macro("'C:Documents and SettingsNHAVDesktopGetData_TestSheet1'!R1C1")
End Sub
– Và cách 2 này chính là phương pháp dùng macro 4 để lấy dữ liệu ở file đang đóng
———————————————————-
– Hãy nghiên cứu chuổi "'C:Documents and SettingsNHAVDesktopGetData_TestSheet1'!R1C1"
Ta thấy nó có cú pháp thế này:
"'" & đường dẩn & "[" Tên file & "]" & Tên sheet & "'!" & địa chỉ cell
– Vậy hãy xây dựng 1 code dựa trên phương pháp lấy dữ liệu này nhé
Function GetData(sFile As String, sSheet As String, sAddr As String)
Dim pLink As String, iR As Long, iC As Long, Arr
If Len(Dir(sFile)) Then
Arr = Range(sAddr)
pLink = "'" & Replace(sFile, Dir(sFile), "[" & Dir(sFile) & "]") & sSheet & "'!"
For iR = 1 To Range(sAddr).Rows.Count
For iC = 1 To Range(sAddr).Columns.Count
Arr(iR, iC) = ExecuteExcel4Macro(pLink & Range(sAddr).Cells(iR, iC).Address(, , 2))
Next iC
Next iR
GetData = Arr
End If
End Function
– Hàm đã có, giờ để lấy dữ liệu vùng A1:D12 tại sheet1 của file Source.xls, ta viết thêm code này:
Sub Test()
Dim sFile As String, sSheet As String, sAddr As String
sFile = ThisWorkbook.Path & "Source.xls"
sSheet = "Sheet1"
sAddr = "A1:D100"
Range("A1:D12") = GetData(sFile, sSheet, sAddr)
End Sub
—————————–
Ứng dụng mở rộng: Nạp list cho ComboBox, với dữ liệu được lấy từ file đang đóng
– Giả sử ta có sẳn 1 ComboBox, tên ComboBox1
– Dữ liệu cần lấy nằm ở vùng H1:H10 của sheet1, file Source.xls
– Ta viết code sau:
Sub AddList()
Dim sFile As String, sSheet As String, sAddr As String
sFile = ThisWorkbook.Path & "Source.xls"
sSheet = "Sheet1"
sAddr = "H1:H10"
Sheet1.ComboBox1.List() = GetData(sFile, sSheet, sAddr)
End Sub
Sau khi chạy code, hãy bấm vào ComboBox xem thử
————————————
Ưu điểm và nhược điểm:
– Ưu điểm của phương pháp dùng macro 4 này là code đơn giản, lại hoàn toàn không mở file tí nào (ngay cả ADO, tuy không thấy mở file nhưng thực chất nó cũng mở ngầm)
– Với ADO hoặc phương thức mở file trực tiếp, dù không biết tên sheet thì ít nhất ta cũng lấy được dữ liệu tại sheet đầu tiên
– Với phương pháp dùng Macro 4, bắt buộc phải biết trước tên sheet
– Còn ưu điểm hay nhược điểm gì nữa.. chúng ta cùng nghiên cứu thêm nhé
————————————
Hãy tham khảo file đính kèm và cảm nhận nhé! Đơn giản không nào?
————————————
Lưu ý quan trọng: Tại file về, phải giải nén ra rồi hẳn chạy, nếu không code chẳng hoạt động đâu nha
www.giaiphapexcel.com/diendan/threads/d%C3%B9ng-macro-4-%C4%91%E1%BB%83-l%E1%BA%A5y-d%E1%BB%AF-li%E1%BB%87u-t%E1%BB%AB-1-file-%C4%91ang-%C4%91%C3%B3ng.39312/
Khoá học Trưởng phòng nhân sự
Nguồn nhân lực là một trong Tứ trụ kinh doanh của doanh nghiệp, có tác động tới sự tồn tại và phát triển bền...
Xem khóa học
Nếu là tôi thì đầu tiên tôi sẽ dùng macro 4, copy toàn bộ dữ liệu tại file nguồn cho vào 1 sheet phụ —> Sau đó muốn làm gì chả được! (xong việc có thể xóa dữ liệu tạm đi)
Thì code này đây:
Sub Test()
Dim sFile As String, sSheet As String, sAddr As String
sFile = ThisWorkbook.Path & "Source.xls"
sSheet = "Sheet1"
sAddr = "A1:D100"
Range("A1:D12") = GetData(sFile, sSheet, sAddr)
End Sub
Dùng để copy ra sheet phụ chứ còn gì nữa… Bạn làm như sau:
– Ở code trên, hãy sửa Source.xls thành Data.xls
– Sửa Sheet1 thành Dinhmuc
– Sửa A1:D12 thành A1:F58
– Chèn thêm 1 sheet, chạy code vừa sửa là có ngay dữ liệu thôi
—————–
Sau khi đã cho dữ liệu vào cùng 1 file thì phần còn lại đó là 1 bài toán khác rồi (sẽ giải quyết ở 1 topic khác, đồng ý không?)
Điều này không bắt buộc, tôi để cùng 1 thư mục để tiện cho quá trình thí nghiệm thôi
Nếu file của bạn nằm ở thư mục khác, cứ ghi đường dẫn chính xác vào là được rồi
Ví dụ đoạn code này:
Sub Test()
Dim sFile As String, sSheet As String, sAddr As String
sFile = ThisWorkbook.Path & "Source.xls"
sSheet = "Sheet1"
sAddr = "A1:D100"
Range("A1:D12") = GetData(sFile, sSheet, sAddr)
End Sub
Nếu file Source.xls nằm ở 1 thư mục khác (D:BaitapSource.xls chẳng hạn) thì sửa code thành:
Sub Test()
Dim sFile As String, sSheet As String, sAddr As String
sFile = "D:BaitapSource.xls"
sSheet = "Sheet1"
sAddr = "A1:D100"
Range("A1:D12") = GetData(sFile, sSheet, sAddr)
End Sub
Vậy thôi
Đây cũng là 1 nhược điểm nữa của phương pháp này!
Với file có Pass Open, khi chạy code chỉ có cách nhập pass bằng tay vào thôi (vì chắc chắn nó sẽ hiện ra 1 khung xác nhận password)
Bạn nói đúng! Vì thế giải pháp này chỉ nên áp dụng với dữ liệu nhỏ mà thôi
Được cái là code đơn giản, dễ nhớ, tự mình xây dựng được! —-> Dù sao thì để lấy dữ liệu khoảng 100 dòng mà mang nguyên cả code dùng ADO ra cũng phí (nhớ được code cũng cả 1 vấn đề)
Đối với trường hợp lấy dữ liệu từ Workbook đang đóng, tôi nghĩ nếu đưa vào mảng sẽ chậm hơn so với cách đưa trực tiếp
Các code ở trên là dùng mảng đấy thôi!
Còn đây là cách không dùng mảng và vòng lập
Sub GetData(sFile As String, sSheet As String, sAddr As String, Target As Range)
Dim pLink As String
If Len(Dir(sFile)) Then
pLink = "'" & Replace(sFile, Dir(sFile), "[" & Dir(sFile) & "]") & sSheet & "'!"
With Range(sAddr)
With Target.Resize(.Rows.Count, .Columns.Count)
.FormulaArray = "=" & pLink & sAddr
.Value = .Value
End With
End With
End If
End Sub
Sub Test()
Dim sFile As String, sSheet As String, sAddr As String
sFile = ThisWorkbook.Path & "Source.xls"
sSheet = "Sheet1"
sAddr = "A1:C10000"
GetData sFile, sSheet, sAddr, Range("A1")
End Sub
Cách này cho tốc độ nhanh hơn, tuy nhiên vẫn có giới hạn (giới hạn bao nhiêu tôi chưa biết) —> Nếu tăng vùng dữ liệu cần lấy (chẳng hạn A1:C60000) thì code sẽ báo lỗi
Còn việc tăng dung lượng gì đó thì… có sao đâu —> Sao khi xong việc, bạn xóa dữ liệu đi là xong chứ gì!
Đương nhiên chỉ có cách dùng ADO là hầu như không bị giới hạn gì cả nhưng ác cái là code rất khó nhớ
Nếu biết chạy code thì chép code sau vào VBA chạy xem nha… nhớ đặt hết tên Sheet trước khi chạy code
Sub Check_SheetCodeName_SheetName()
Dim Sh As Worksheet
For Each Sh In Worksheets
MsgBox "Day La Sheet Name :" & Space(1) & Sh.Name, 64, "Thông Báo"
MsgBox "Day La Sheet CodeName :" & Space(1) & Sh.CodeName, 64, "Thông Báo"
Next Sh
End Sub
Không có cách nào đâu bạn! Dù có cũng sẽ rất phức tạp, không đáng để nghiên cứu