Tìm hàm, để code gán xuống sheet thì thành chữ việt có dấu

Em chào anh chị,
Trước đây em có đọc bài là đổi chữ tiếng Việt có dấu chuyển thành chữ để đưa vào code
Ví dụ tại ô A1 em gõ Kế toán trưởng thì ô b1 dùng hàm gì đó để kết quả là
"K" & ChrW(7871) & " toán tr" & ChrW(432) & ChrW(7903) & "ng"
Em có tải file đó về nhưng vừa rồi em bị xóa file đó, nên em tìm lại, hàm tên un… gì đó
Nhờ anh chị có thì cho em xin hoặc chỉ cho em , em cảm ơn

Không nên
"K" & ChrW(7871) & " toán tr" & ChrW(432) & ChrW(7903) & "ng"

mà nên là
"K" & ChrW(7871) & " to" & ChrW(225) & "n tr" & ChrW(432) & ChrW(7903) & "ng"

Đã thay thế ký tự Việt bằng ChrW(…) thì làm toàn bộ, không chơi kiểu nửa vời. Nên nhớ là trên một số máy thì ở chỗ " toán tr" ta thấy "á" nhưng ở một số máy sẽ có "đầu trâu mặt ngựa" thay cho "á".

Function TaoChuoiMa(ByVal text As String) As String
Dim k As Long, start As Long, kytu As String, s As String, result As String
    s = text
    start = 1
    For k = 1 To Len(s)
        kytu = Mid(s, k, 1)
        If AscW(kytu) > 127 Then
            If start < k Then
                result = result & " & " & Chr(34) & Mid(s, start, k - start) & Chr(34) & " & ChrW(" & AscW(kytu) & ")"
            Else
                result = result & " & ChrW(" & AscW(kytu) & ")"
            End If
            start = k + 1
        End If
    Next k
    If start < k Then result = result & " & " & Chr(34) & Mid(s, start, k - start) & Chr(34)
    If Left(result, 2) = " &" Then result = Mid(result, 4)
    TaoChuoiMa = result
End Function

Cách dùng

=TaoChuoiMa(A1)

www.giaiphapexcel.com/diendan/threads/t%C3%ACm-h%C3%A0m-%C4%91%E1%BB%83-code-g%C3%A1n-xu%E1%BB%91ng-sheet-th%C3%AC-th%C3%A0nh-ch%E1%BB%AF-vi%E1%BB%87t-c%C3%B3-d%E1%BA%A5u.160446/#post-1071001

Khóa học SprinGO phù hợp

Khóa học Power PI – Ứng dung trong Nhân sự

TỔNG QUAN KHÓA HỌC: POWER BI CHO NGÀNH NHÂN SỰ Khóa học Power BI cho Nhân sự được thiết kế dành riêng cho các...

Xem khóa học