Dò tìm theo nhiều điều kiện

Chia sẻ bởi:hands

★★★★★

‹ Hàm IF trong excel HelP: Tìm kiếm giá trị với 2... ›

Quảng cáo

Nhờ các anh chị trên diễn đàn hướng dẫn giúp mình cách thiết lập công thức hoặc hàm người dùng theo nhiều điều kiện trong File đính kèm dưới đây. Mình đã tìm nhiều trên diễn đàn nhưng chưa thấy. Xin cám ơn

Gõ vào cell E22 công thức sau:
=LOOKUP(2,1/(($A$2:$A$12=$C22)*($B$2:$B$12<=$D22)),$C$2:$C$12)

ndu vui lòng giải nghĩa tiếp công thức này. Thanks!

Anh bôi đen đoạn ($A$2:$A$12=$C22)*($B$2:$B$12<=$D22) trên thanh Formula rồi bấm F9, để ý kết quả là gì
Tiếp theo, bôi đên đoạn 1/(($A$2:$A$12=$C22)*($B$2:$B$12<=$D22)) trên thanh Formula rồi cũng bấm F9, xem kết quả là gì
===> Suy ra điều mà anh cần giải thích
Cái trò này em áp dụng từ đây:
https://www.giaiphapexcel.com/forum/showthread.php?7669-Nh%E1%BB%AFng-c%C3%B4ng-th%E1%BB%A9c-%C4%91%E1%BB%99c-%C4%91%C3%A1o&

Tình cờ tôi thu thập dc 1 số công thức có thể nói là độc đáo… Xin post lên đễ chia sẽ với mọi người:
1> Công thức lấy giá trị dạng Number nằm ở vị trí cuối cùng trong 1 cột
Giã sử cột A chứa dử liệu vừa số vừa chuổi, với công thức dưới đây ta sẽ lấy dc số nằm ở vị trị cuối cùng trong cột A này:
=INDEX(A:A,MATCH(9.99999999999999E+307,A:A))
2> Công thức lấy giá trị dạng Text nằm ở vị trí cuối cùng trong 1 cột:
Tương tự công thức trên, nhưng là lấy giá trị Text
=INDEX(A:A,MATCH(REPT("Z",255),A:A))
3> Công thức lấy giá trị nằm ở vị trí cuối cùng trong cột, bất kỳ dàng nào:
=LOOKUP(2,1/(1-ISBLANK(A1:A65535)),A1:A65535)
—–
Chú ý: công thức 1 sẽ cho kết quã #NA nếu cột A ko có số nào
Mời các cao thủ nếu có thu thập dc món nào tuyệt chiêu thì post lên ũng hộ topic này nhé!
Mến
ANH TUẤN

Nói tóm lại, công thức dạng LOOKUP(2, 1/(Biểu thức gì đó), Vùng chứa dữ liệu cần tìm) là để tìm cell cuối cùng thỏa điều kiện nào đó
Mục đích của ta là làm cách nào để biểu thức (Biểu thức gì đó) trở thành 1 Array mà tất cả các phần tử của nó là 0 và 1 (với những em thỏa đ/k sẽ =1 và ngược lại) —> Vậy 1/(Biểu thức gì đó) sẽ là 1 Array mà các phần tử của nó là 1 hoặc #DIV/0! (với những em thỏa đ/k sẽ =1 và ngược lại)
===> Tìm số 2 trong một mảng chỉ có số 1 và #DIV/0! thì đương nhiên nó sẽ lấy số 1 cuối cùng trong mảng, tra qua bên vùng chứa dữ liệu cần tìm để lấy kết quả tương ứng

Em mạn phép edu giải thích theo cách hiểu nôm na của em nhé.
+-+-+-+

Vậy muốn tìm cell đầu tiên thỏa mãn điều kiện thì công thức Lookup viết như thế nào ? Nhờ các bạn vui lòng chỉ giúp. Thanks!

Ẹc… Ẹc… Cái vụ tìm cell đầu thỏa điều kiện thì ta đâu có dùng LOOKUP —> dùng VLOOKUP hoặc MATCH với kiểu dò = 0 thôi

Ndu ơi vậy tôi muốn dò tìm cell đầu thỏa nhiều điều kiện như tên Topic này thì công thức viết như thế nào ?

Cứ cái gì liên quan đến việc TÌM GIÁ TRỊ ĐẦU TIÊN thì anh cứ nghĩ đến MATCH đi —> Bao nhiêu điều kiện cũng mặc kệ (MATCH với kiểu dò = 0 và trị dò phải theo kiểu tìm chính xác)

Em có tình huống này tìm theo 4 điều kiện thì phải làm sao .Nhờ các anh chị và các bạn giúp nhé.Xin cám ơn.

Gõ vào cell J3 công thức này:

=LOOKUP(2,1/(($A$3:$A$100=$F9)*($B$3:$B$100=$G9)*($C$3:$C$100=$H9)*($D$3:$D$100=$I9)),$E$3:$E$100)

Nhờ anh giải thích cho cho em cái chỗ 2,1/ ý nghĩa ra sao vậy anh .
Nếu em chỉ còn 3 dk thì chỉnh cái chỗ 2.1/ là thành bao nhiu vậy.
Cám ơn anh

– Trong công thức trên thì (($A$3:$A$100=$F9)*($B$3:$B$100=$G9)*($C$3:$C$100=$H9)*($D$3:$D$100=$I9)) là nhóm điều kiện. Các mảng này nhân với nhau sẽ ra các giá trị TRUE hoặc FALSE tùy thuộc điều kiện là đúng hay sai
– 1/(($A$3:$A$100=$F9)*($B$3:$B$100=$G9)*($C$3:$C$100=$H9)*($D$3:$D$100=$I9)) —> Số 1 chia cho 1 mảng mà các phần tử của nó là TRUE và FALSE thì sẽ cho kết quả = 1 hoặc = #DIV/0! (chia cho TRUE tương đương chia cho 1 nên ra kết quả =1… Chia cho FALSE tương đương chia cho 0 nên ra kết quả là #DIV/0!). Tạm gọi đây là KQ1
– LOOKUP(2, KQ1, Mảng kết quả) —> Dò số 2 trong KQ1, nó sẽ tra và lấy số 1 cuối cùng, dò sang mảng kết quả
—————
Nói thêm: Không nhất thiết phải là số 2… Số nào cũng được, miễn > 1

Tại sao lại là lấy số 1 cuối cùng nhỉ, mình vẫn chưa hiểu lắm, Trong mảng KQ1 có thể có nhiều giá trị đúng (tức là 1) vậy tại sao lại lấy số 1 cuối cùng mà không phải là một số 1 nào đó trong mảng??

Trường hợp chỉ có 1 số 1 thôi, vì trong 1 ngày nhất định, 1 ca nhất định, 1 máy nhất định, 1 code nhất định chì có 1 người.

KQ1: #DIV/0, #DIV/0, 1, #DIV/0, #DIV/0
KQ : A, B , C, D, E
Kết quả: C